home *** CD-ROM | disk | FTP | other *** search
/ Revista do CD-ROM 101 / CD-ROM 101.iso / compl / maya5ple / Install_MayaPLE5_English.exe / Maya / Data1.cab / cleanUpScene.mel < prev    next >
Encoding:
Text File  |  2003-07-17  |  32.8 KB  |  1,107 lines
  1. // Copyright (C) 1997-2002 Alias|Wavefront,
  2. // a division of Silicon Graphics Limited.
  3. //
  4. // The information in this file is provided for the exclusive use of the
  5. // licensees of Alias|Wavefront.  Such users have the right to use, modify,
  6. // and incorporate this code into other products for purposes authorized
  7. // by the Alias|Wavefront license agreement, without fee.
  8. //
  9. // ALIAS|WAVEFRONT DISCLAIMS ALL WARRANTIES WITH REGARD TO THIS SOFTWARE,
  10. // INCLUDING ALL IMPLIED WARRANTIES OF MERCHANTABILITY AND FITNESS, IN NO
  11. // EVENT SHALL ALIAS|WAVEFRONT BE LIABLE FOR ANY SPECIAL, INDIRECT OR
  12. // CONSEQUENTIAL DAMAGES OR ANY DAMAGES WHATSOEVER RESULTING FROM LOSS OF USE,
  13. // DATA OR PROFITS, WHETHER IN AN ACTION OF CONTRACT, NEGLIGENCE OR OTHER
  14. // TORTIOUS ACTION, ARISING OUT OF OR IN CONNECTION WITH THE USE OR
  15. // PERFORMANCE OF THIS SOFTWARE.
  16. //
  17. //
  18. // Alias|Wavefront Script File
  19. //
  20. // Creation Date:  
  21. // Author:         
  22. //
  23. //
  24. //  Procedure Name:
  25. //      cleanUpScene
  26. //
  27. //  Description:
  28. //      This procedure invokes the clean up scene operations.
  29. //
  30. //  Input Arguments:
  31. //
  32. //  Return Value:
  33. //      None.
  34. //
  35.  
  36. global proc string[] listEmptyGroups( ) 
  37. //
  38. //    Lists groups with no relatives or connections,
  39. //    and supplies them to the calling proc to
  40. //    do with as needed.
  41. //
  42. {
  43.     string $obj;
  44.     string $unused[];
  45.     string $xforms[] = `ls -transforms -leaf`;
  46.     for( $obj in $xforms ) {
  47.         if( size( listRelatives("-c", $obj) ) == 0 ) {
  48.             if( `objectType $obj` == "transform") {
  49.                 string $conn[] = `listConnections($obj)`;
  50.                 if( size( $conn ) == 0 ) {
  51.                     $unused[size($unused)] = $obj;
  52.                 } else if( (size( $conn ) == 1)
  53.                        &&  (`objectType $conn[0]` == "displayLayer") ) {
  54.                     $unused[size($unused)] = $obj;
  55.                 } else if( (size( $conn ) == 1)
  56.                        &&  (`objectType $conn[0]` == "renderLayer") ) {
  57.                     $unused[size($unused)] = $obj;
  58.                 }
  59.             }
  60.         }
  61.     }
  62.     return $unused;
  63. }
  64.  
  65. global proc deleteEmptyGroups( ) 
  66. //
  67. //    Deletes anything returned by listEmptyGroups,
  68. //    until the list itself is empty
  69. //
  70. {
  71.     int $i;
  72.     string $unused[] = `listEmptyGroups`;
  73.     int $numTransf = size(`ls -transforms`);
  74.     int $numUnused = size($unused);
  75.     while ( $numUnused > 0 ) {
  76.         for ($i = 0; $i < size($unused); $i++) {
  77.             deleteIfNotReferenced( $unused[$i] );
  78.         }
  79.         $unused = `listEmptyGroups`;
  80.  
  81.         // 132335: need to avoid infinite loop possibility
  82.         // if referenced files - nothing deleted.
  83.         if (size($unused) == $numUnused &&
  84.             size(`ls -transforms`) == $numTransf) {
  85.             break;
  86.         } else {
  87.             $numUnused = size($unused);
  88.             $numTransf = size(`ls -transforms`);
  89.         }
  90.     }
  91. }
  92.  
  93. global proc deleteEmptyLayers(string $type)
  94. //
  95. // If $type == "Display" then delete display layers
  96. // If $type == "Render" then delete render layers
  97. //
  98. {
  99.     string $objectType, $layer;
  100.     string $layerArray[], $layerContents[];
  101.  
  102.     if ("Display" == $type) {
  103.         $objectType = "displayLayer";
  104.     } else {
  105.         $objectType = "renderLayer";
  106.     }
  107.  
  108.     //    Get all layers of the appropriate type.
  109.     //
  110.     $layerArray = `ls -type $objectType`;
  111.  
  112.     //    Determine the contents of each layer. Ignore default layers.
  113.     //
  114.     int $index = 0;
  115.     for ($layer in $layerArray) {
  116.  
  117.         //    Ignore default layers. Default layers have an id of 0.
  118.         //
  119.         if (0 < `getAttr ($layer + ".identification")`) {
  120.             if ("Display" == $type) {
  121.                 $layerContents = `editDisplayLayerMembers -query $layer`;
  122.             } else if ("Render" == $type) {
  123.                 $layerContents = `editRenderLayerMembers -query $layer`;
  124.             }
  125.             if (0 == size($layerContents)) {
  126.                 //
  127.                 //    This layer has nothing in it. Delete it.
  128.                 //
  129.                 deleteIfNotReferenced ($layer);
  130.             }
  131.         }
  132.     }
  133. }
  134.  
  135. proc getAllParents(string $node, string $resultParents[])
  136. //
  137. // Description:
  138. //      Procedure to find all the parents at all levels above the specified
  139. //      node. The parent names will be appended to resultParents.
  140. //
  141. // Arguments:
  142. //      node            Name of node to get parents for.
  143. //      resultParents   Array to append parent names to.
  144. //
  145. // Author:
  146. //      cdt (March 2002)
  147. //
  148. {
  149.     string $parents[] = `listRelatives -allParents -fullPath $node`;
  150.  
  151.     for ($parent in $parents) {
  152.         // Append to the end of the list.
  153.         $resultParents[size($resultParents)] = $parent;
  154.  
  155.         getAllParents($parent, $resultParents);
  156.     }
  157. }
  158.  
  159. global proc deleteUnusedConstraints()
  160. //
  161. // Description:
  162. //  Deletes constraints that are not constraining any objects.
  163. //
  164. { 
  165.     string $constraintTypes[] = { "pointConstraint",
  166.                                   "aimConstraint",
  167.                                   "orientConstraint",
  168.                                   "parentConstraint",
  169.                                   "scaleConstraint",
  170.                                   "normalConstraint",
  171.                                   "tangentConstraint",
  172.                                   "geometryConstraint"};
  173.     for ($typ in $constraintTypes) {
  174.         string $constraints[] = `ls -type $typ`;
  175.  
  176.         // Is the constraint driving anything?
  177.         //
  178.         for ($constraint in $constraints) {
  179.             // are there any outgoing connections?
  180.             //
  181.             string $conns[] = `listConnections -s 0 -d 1 $constraint`;
  182.  
  183.             int $deleteIt = 1;
  184.             for ($conn in $conns) {
  185.                 // ignore outgoing connections that lead to this node itself
  186.                 // (constraints connect their weight attribute to a dynamic weight
  187.                 // attribute)
  188.                 //
  189.                 if ($conn != $constraint) {
  190.                     $deleteIt = 0;
  191.                     break;
  192.                 }
  193.             }
  194.             if ($deleteIt) {
  195.                 deleteIfNotReferenced($constraint);
  196.             }
  197.         }
  198.     }
  199. }
  200.  
  201. global proc deleteUnusedPairBlends()
  202. //
  203. // Description:
  204. //  Deletes pairBlends that meet the following criteria:
  205. //   1. have no outputs, or
  206. //   2. have no connections to input2    
  207. //
  208. { 
  209.     string $pairBlends[] = `ls -type pairBlend`;
  210.     for ($pairBlend in $pairBlends) {
  211.         int $deleteIt = 0;
  212.         string $conns[] = `listConnections -s 0 -d 1 $pairBlend`;
  213.         if (0 == size($conns)) {
  214.             $deleteIt = 1;
  215.         } else {
  216.             string $inputs[] = `pairBlend -q -input2 $pairBlend`;
  217.             if (0 == size($inputs)) {
  218.                 $deleteIt = 1;
  219.             }
  220.         }
  221.         if ($deleteIt) {
  222.             deleteIfNotReferenced($pairBlend);
  223.         }
  224.     }
  225. }
  226.  
  227. global proc deleteUnusedLocators()
  228. // 
  229. // Desription:
  230. //    Deletes those locator objects that don't have connections
  231. //    to either their shape or transform nodes. 
  232. //
  233. {
  234.     int $i, $j, $shapeConnections, $parentConnections;
  235.     string $nodeList[] = `ls -typ locator`;
  236.     string $connectionList[];
  237.     string $parent[];
  238.  
  239.     for ($i = 0; $i < size($nodeList); $i++) {
  240.         // Check if the locator shape is connected
  241.         //
  242.         string $locatorShape = $nodeList[$i];
  243.  
  244.         $connectionList = `listConnections $locatorShape`;
  245.         $numConnections = size($connectionList);
  246.         if ($numConnections == 0)
  247.         {
  248.             // Check if the locator transform is connected
  249.             //
  250.             clear($parent);
  251.             getAllParents($nodeList[$i], $parent);
  252.             int $parentOK = true;
  253.             for($j = 0; $j < size($parent); $j++)
  254.             {
  255.                 string $parentNode = $parent[$j];
  256.                 $connectionList = `listConnections $parentNode`;
  257.                 $parentConnections = size($connectionList);
  258.                 if ($parentConnections != 0)
  259.                 {
  260.                     $parentOK = false;
  261.                     break;
  262.                 }
  263.                 
  264.             }
  265.             if ($parentOK)
  266.             {
  267.                 for($j=0;$j<size($parent);$j++)
  268.                 {
  269.                     $parentNode = $parent[$j];
  270.  
  271.                     // Don't remove the locator transform if there are  
  272.                     // objects parented under it other than the locator
  273.                     // shape
  274.                     //
  275.                     string $childL[] = `listRelatives -c $parentNode`;
  276.                     if (size($childL) > 1)
  277.                         continue;
  278.                     
  279.                     deleteIfNotReferenced( $parentNode );
  280.                 }
  281.             }
  282.         }
  283.     }
  284. }
  285.  
  286.  
  287. //
  288. //    cleanUpScene:
  289. //        $option = 1: does the cleanup operation
  290. //        $option = 2: option window for cleanup
  291. //        $option = 3: cleanup operation for everything regardless of options
  292. //
  293. global proc cleanUpScene (int $option)
  294. {
  295.     if ($option == 1) {    
  296.         // Do the cleanup
  297.         setOptionVars (false);
  298.         performCleanUpScene();
  299.     } else if ($option == 2) {
  300.         // Option window for the cleanup work
  301.         cleanUpOptions();
  302.     } else if ($option == 3) {
  303.         performCleanUpSceneForEverything();
  304.     }
  305. }
  306.  
  307.  
  308. //
  309. //    invokes the MEL procs to start deleting the unused database.
  310. //
  311. global proc performCleanUpScene ()
  312. {
  313.     // Confirm that a cleanup is desired (since this is not undoable)
  314.     string $result = `confirmDialog 
  315.         -title "Verifying Action"
  316.         -message "Optimize current scene size?\nThis action is not undoable." 
  317.         -button "OK" -button "Cancel"`; 
  318.     
  319.     if (!`about -batch` && $result != "OK") {
  320.         return;
  321.     }
  322.  
  323.     print "\n";
  324.  
  325.     if (`optionVar -query nurbsSrfOption`) {
  326.         print "Removing invalid nurbs surfaces\n";
  327.         print "-------------------------------\n";
  328.         deleteInvalidNurbs(0);
  329.  
  330.         // These nodes can be considered "invalid" 
  331.         // if they have no connections.  The list is
  332.         // far from complete; we'll add to it as needed.
  333.         //
  334.         deleteUnusedCommon( "stitchSrf", 0 );
  335.         deleteUnusedCommon( "rebuildSurface", 0 );
  336.         deleteUnusedCommon( "insertKnotSurface", 0 );
  337.         deleteUnusedCommon( "avgNurbsSurfacePoints", 0 );
  338.         print "\n";
  339.     }
  340.  
  341.     if (`optionVar -query nurbsCrvOption`) {
  342.         print "Removing unused nurbs curves\n";
  343.         print "----------------------------\n";
  344.         deleteUnusedInUnusedHierarchy("nurbsCurve", 0);
  345.         print "\n";
  346.     }
  347.  
  348.     if (`optionVar -query locatorOption`) {
  349.         print "Removing unused locators\n";
  350.         print "------------------------\n";
  351.         deleteUnusedLocators();
  352.         print "\n";
  353.     }
  354.  
  355.     if (`optionVar -query ptConOption`) {
  356.         print "Removing unused constraints\n";
  357.         print "---------------------------------\n";
  358.         deleteUnusedConstraints();
  359.         print "\n";
  360.     }
  361.  
  362.     if (`optionVar -query pbOption`) {
  363.         print "Removing unused pairBlends\n";
  364.         print "---------------------------------\n";
  365.         deleteUnusedPairBlends();
  366.         print "\n";
  367.     }
  368.  
  369.     if (`optionVar -query deformerOption`) {
  370.         print "Removing unused deformers\n";
  371.         print "-------------------------\n";
  372.         deleteUnusedDeformers();
  373.         print "\n";
  374.     }
  375.  
  376.     if (`optionVar -query expressionOption`) {
  377.         print "Removing unused expressions\n";
  378.         print "---------------------------\n";
  379.         deleteUnusedExpressions();
  380.         print "\n";
  381.     }
  382.  
  383.     if (`optionVar -query groupIDnOption`) {
  384.         print "Removing unused groupID nodes\n";
  385.         print "-----------------------------\n";
  386.         deleteUnusedCommon("groupId", 1);
  387.         print "\n";
  388.     }
  389.  
  390.     if (`optionVar -query animationCurveOption`) {
  391.         print "Removing unused animation curves\n";
  392.         print "--------------------------------\n";
  393.         deleteUnusedCommon("animCurve", 0);
  394.         print "\n";
  395.     }
  396.  
  397.     if (`optionVar -query clipOption`) {
  398.         print "Removing unused animation clips\n";
  399.         print "-------------------------\n";
  400.         deleteUnusedTrax("clips");
  401.         print "\n";
  402.     }
  403.  
  404.     if (`optionVar -query poseOption`) {
  405.         print "Removing unused animation poses\n";
  406.         print "-------------------------\n";
  407.         deleteUnusedTrax("poses");
  408.         print "\n";
  409.     }
  410.  
  411.     if (`optionVar -query snapshotOption`) {
  412.         print "Removing unused snapshot nodes\n";
  413.         print "------------------------------\n";
  414.         deleteUnusedCommon("snapshot", 1);
  415.         print "\n";
  416.     }
  417.  
  418.     if (`optionVar -query unitConversionOption`) {
  419.         print "Removing unused unit conversion nodes\n";
  420.         print "-------------------------------------\n";
  421.         deleteUnusedCommon("unitConversion", 1);
  422.         deleteUnusedCommon("timeToUnitConversion", 1);
  423.         deleteUnusedCommon("unitToTimeConversion", 1);
  424.         print "\n";
  425.     }
  426.  
  427.     if (`optionVar -query shaderOption`) {
  428.         print "Removing unused rendering nodes\n";
  429.         print "-------------------------------\n";
  430.         MLdeleteUnused();
  431.         print "\n";
  432.     }
  433.  
  434.     if (`optionVar -query cachedOption`) {
  435.         print "Removing cached data in datablocks\n";
  436.         print "----------------------------------\n";
  437.         int $cleared = `clearCache -allNodes`;
  438.         print( "Cleaned out " + $cleared + " datablocks\n");
  439.         print "\n";
  440.     }
  441.  
  442.     if (`optionVar -query transformOption`) {
  443.         print "Removing empty transforms\n";
  444.         print "-------------------------\n";
  445.         deleteEmptyGroups();
  446.         print "\n";
  447.     }
  448.  
  449.     if (`optionVar -query displayLayerOption`) {
  450.         print "Removing empty display layers\n";
  451.         print "-----------------------------\n";
  452.         deleteEmptyLayers("Display");
  453.         print "\n";
  454.     }
  455.  
  456.     if (`optionVar -query renderLayerOption`) {
  457.         print "Removing empty render layers\n";
  458.         print "-----------------------------\n";
  459.         deleteEmptyLayers("Render");
  460.         print "\n";
  461.     }
  462.  
  463.     if (`optionVar -query setsOption`) {
  464.         print "Removing empty sets\n";
  465.         print "-------------------\n";
  466.         deleteUnusedSets();
  467.         print "\n";
  468.     }
  469.  
  470.     if (`optionVar -query partitionOption`) {
  471.         print "Removing empty partitions\n";
  472.         print "-------------------------\n";
  473.         deleteUnusedCommon("partition", 0);
  474.         print "\n";
  475.     }
  476.  
  477.     if (`optionVar -query referencedOption`) {
  478.         print "Removing unused referenced items\n";
  479.         print "--------------------------------\n";
  480.         RNdeleteUnused();
  481.         print "\n";
  482.     }
  483.  
  484.     if (`optionVar -query brushOption`) {
  485.         print "Removing unused Brushes\n";
  486.         print "--------------------------------\n";
  487.         deleteUnusedBrushes();
  488.         print "\n";
  489.     }
  490.  
  491.     print "Scene optimized - check Script Editor for details.\n";
  492. }
  493.  
  494.  
  495. //
  496. //    same as performCleanUpScene, except everything is cleaned up
  497. //
  498. global proc performCleanUpSceneForEverything ()
  499. {
  500.     print "\nClean up database\n";
  501.     print "-----------------\n\n";
  502.  
  503.     deleteInvalidNurbs(0);
  504.     deleteUnusedCommon( "stitchSrf", 0 );
  505.     deleteUnusedCommon( "rebuildSurface", 0 );
  506.     deleteUnusedCommon( "insertKnotSurface", 0 );
  507.     deleteUnusedCommon( "avgNurbsSurfacePoints", 0 );
  508.     deleteUnusedCommon("nurbsCurve", 0);
  509.     deleteUnusedLocators();
  510.     deleteUnusedConstraints();
  511.     deleteUnusedPairBlends();    
  512.     deleteUnusedDeformers();
  513.     deleteUnusedExpressions();
  514.     deleteUnusedCommon("groupId", 1);
  515.     deleteUnusedCommon("animCurve", 0);
  516.     deleteUnusedCommon("snapshot", 1);
  517.     deleteUnusedCommon("unitConversion", 1);
  518.     deleteUnusedCommon("timeToUnitConversion", 1);
  519.     deleteUnusedCommon("unitToTimeConversion", 1);
  520.     MLdeleteUnused();
  521.     clearCache -allNodes;
  522.     deleteEmptyGroups();
  523.     deleteEmptyLayers("Display");
  524.     deleteEmptyLayers("Render");
  525.     deleteUnusedSets();
  526.     deleteUnusedCommon("partition", 0);
  527.     RNdeleteUnused();
  528.     deleteUnusedBrushes();
  529.  
  530.     print "\n";
  531. }
  532.  
  533.  
  534. //
  535. //    option box layout for cleanup
  536. //
  537. global proc cleanUpOptions ()
  538. {
  539.     string $commandName = "cleanUpScene";
  540.     string $callback = ($commandName + "Callback");
  541.     string $setup = ($commandName + "Setup");
  542.  
  543.     string $layout = getOptionBox();
  544.     setParent $layout;
  545.  
  546.     setOptionBoxCommandName($commandName);
  547.  
  548.     string $tabLayout = `tabLayout -scrollable 1`;
  549.     tabLayout -edit
  550.         -tabsVisible false
  551.         -preSelectCommand ("createCleanUpSceneTabUI " + $tabLayout)
  552.         $tabLayout;
  553.     columnLayout -adj true;
  554.         setParent ..;
  555.     tabLayout -edit
  556.         $tabLayout;
  557.  
  558.     createCleanUpSceneTabUI($tabLayout);
  559.  
  560.  
  561.     //  Std buttons for options.
  562.     //
  563.     string $applyBtn = getOptionBoxApplyBtn();
  564.     button -edit -l "Optimize"
  565.         -command ($callback + " " + $tabLayout + " " + 1 + "; performCleanUpScene")
  566.         $applyBtn;
  567.     string $saveBtn = getOptionBoxSaveBtn();
  568.     button -edit
  569.         -command ($callback + " " + $tabLayout + " " + 0 + "; hideOptionBox")
  570.         $saveBtn;
  571.     string $resetBtn = getOptionBoxResetBtn();
  572.     button -edit
  573.         -command ($setup + " " + $tabLayout + " " + 1)
  574.         $resetBtn;
  575.  
  576.     setOptionBoxTitle("Optimize Scene Size Options");
  577.  
  578.     //    Customize the 'Help' menu item text.
  579.     //
  580.     setOptionBoxHelpTag( "OptimizeSceneSize" );
  581.  
  582.     showOptionBox();
  583. }
  584.  
  585.  
  586. global proc createCleanUpSceneTabUI (string $tabLayout)
  587. {
  588.     string $tab[] = `tabLayout -query -childArray $tabLayout`;
  589.     int $currentTabIndex = `tabLayout -query -selectTabIndex $tabLayout`;
  590.  
  591.     if (0 == `columnLayout -query -numberOfChildren $tab[$currentTabIndex-1]`) {
  592.  
  593.         setParent $tab[$currentTabIndex-1];
  594.  
  595.         string $label;
  596.         int $index;
  597.  
  598.         setUITemplate -pushTemplate attributeEditorTemplate;
  599.  
  600.         waitCursor -state 1;
  601.  
  602.         if (1 == $currentTabIndex) {
  603.             checkBoxGrp -ncb 1 -label "Remove Invalid"
  604.                 -label1 "NURBS Surfaces + Curves" nurbsSrfOption;
  605.  
  606.             separator;            
  607.  
  608.             checkBoxGrp -ncb 1 -label "Remove Empty"
  609.                 -label1 "Sets" setsOption;
  610.             checkBoxGrp -ncb 1
  611.                 -label1 "Partitions" partitionOption;
  612.             checkBoxGrp -ncb 1 
  613.                 -label1 "Transforms" transformOption;
  614.             checkBoxGrp -ncb 1 
  615.                 -label1 "Display Layers" displayLayerOption;
  616.             checkBoxGrp -ncb 1 
  617.                 -label1 "Render Layers" renderLayerOption;
  618.  
  619.             separator -w 490;            
  620.  
  621.             checkBoxGrp -ncb 1  -label "Remove Unused"
  622.                 -label1 "Animation Curves" animationCurveOption;
  623.             checkBoxGrp -ncb 1 -label1 "Animation Clips" clipOption;            
  624.             checkBoxGrp -ncb 1 -label1 "Poses" poseOption;
  625.             checkBoxGrp -ncb 1 -label1 "NURBS Curves" -value1 false nurbsCrvOption;
  626.             checkBoxGrp -ncb 1 -label1 "Cached Data" -value1 false cachedOption;
  627.             checkBoxGrp -ncb 1 -label1 "Deformers" deformerOption;
  628.             checkBoxGrp -ncb 1 -label1 "Expressions" -value1 false expressionOption;
  629.             checkBoxGrp -ncb 1 -label1 "GroupID Nodes" groupIDnOption;
  630.             checkBoxGrp -ncb 1 -label1 "Rendering Nodes" shaderOption;
  631.             checkBoxGrp -ncb 1 -label1 "Locators" locatorOption;
  632.             checkBoxGrp -ncb 1 -label1 "Constraints" ptConOption;
  633.             checkBoxGrp -ncb 1 -label1 "Pair Blends" pbOption;            
  634.             checkBoxGrp -ncb 1 -label1 "Snapshot Nodes" snapshotOption;
  635.             checkBoxGrp -ncb 1 -label1 "Unit Conversion Nodes" 
  636.                 unitConversionOption;
  637.             checkBoxGrp -ncb 1 -label1 "Referenced Items" referencedOption;
  638.             checkBoxGrp -ncb 1 -label1 "Brushes" brushOption;
  639.  
  640.             setParent ..;
  641.         }
  642.  
  643.         eval (("cleanUpSceneSetup " + $tabLayout + " " + 0));
  644.  
  645.         waitCursor -state 0;
  646.         setUITemplate -popTemplate;
  647.     }
  648. }
  649.  
  650.  
  651. //
  652. //    intialize the options for cleanup
  653. //
  654. global proc setOptionVars(int $forceFactorySettings)
  655. {
  656.     if ($forceFactorySettings || !`optionVar -exists nurbsSrfOption`)
  657.         optionVar -intValue nurbsSrfOption true;
  658.     if ($forceFactorySettings || !`optionVar -exists nurbsCrvOption`)
  659.         optionVar -intValue nurbsCrvOption false;
  660.     if ($forceFactorySettings || !`optionVar -exists deformerOption`)
  661.         optionVar -intValue deformerOption true;
  662.     if ($forceFactorySettings || !`optionVar -exists poseOption`)
  663.         optionVar -intValue poseOption false;
  664.     if ($forceFactorySettings || !`optionVar -exists clipOption`)
  665.         optionVar -intValue clipOption false;
  666.     if ($forceFactorySettings || !`optionVar -exists expressionOption`)
  667.         optionVar -intValue expressionOption false;
  668.     if ($forceFactorySettings || !`optionVar -exists groupIDnOption`)
  669.         optionVar -intValue groupIDnOption true;
  670.     if ($forceFactorySettings || !`optionVar -exists animationCurveOption`)
  671.         optionVar -intValue animationCurveOption true;
  672.     if ($forceFactorySettings || !`optionVar -exists shaderOption`)
  673.         optionVar -intValue shaderOption true;
  674.     if ($forceFactorySettings || !`optionVar -exists cachedOption`)
  675.         optionVar -intValue cachedOption false;
  676.     if ($forceFactorySettings || !`optionVar -exists transformOption`)
  677.         optionVar -intValue transformOption true;
  678.     if ($forceFactorySettings || !`optionVar -exists displayLayerOption`)
  679.         optionVar -intValue displayLayerOption true;
  680.     if ($forceFactorySettings || !`optionVar -exists renderLayerOption`)
  681.         optionVar -intValue renderLayerOption true;
  682.     if ($forceFactorySettings || !`optionVar -exists setsOption`)
  683.         optionVar -intValue setsOption true;
  684.     if ($forceFactorySettings || !`optionVar -exists partitionOption`)
  685.         optionVar -intValue partitionOption false;
  686.     if ($forceFactorySettings || !`optionVar -exists locatorOption`)
  687.         optionVar -intValue locatorOption false;
  688.     if ($forceFactorySettings || !`optionVar -exists ptConOption`)
  689.         optionVar -intValue ptConOption true;
  690.     if ($forceFactorySettings || !`optionVar -exists pbOption`)
  691.         optionVar -intValue pbOption true;
  692.     if ($forceFactorySettings || !`optionVar -exists snapshotOption`)
  693.         optionVar -intValue snapshotOption true;
  694.     if ($forceFactorySettings || !`optionVar -exists unitConversionOption`)
  695.         optionVar -intValue unitConversionOption true;
  696.     if ($forceFactorySettings || !`optionVar -exists referencedOption`)
  697.         optionVar -intValue referencedOption true;
  698.     if ($forceFactorySettings || !`optionVar -exists brushOption`)
  699.         optionVar -intValue brushOption true;
  700. }
  701.  
  702.  
  703. //
  704. //    callback to set the values based on current settings
  705. //
  706. global proc cleanUpSceneCallback(string $parent, int $doIt)
  707. {
  708.     setParent $parent;
  709.     
  710.     if (`checkBoxGrp -exists nurbsSrfOption`) {
  711.         optionVar -intValue nurbsSrfOption
  712.             `checkBoxGrp -query -value1 nurbsSrfOption`;
  713.     }
  714.     if (`checkBoxGrp -exists nurbsCrvOption`) {
  715.         optionVar -intValue nurbsCrvOption
  716.             `checkBoxGrp -query -value1 nurbsCrvOption`;
  717.     }
  718.     if (`checkBoxGrp -exists deformerOption`) {
  719.         optionVar -intValue deformerOption
  720.             `checkBoxGrp -query -value1 deformerOption`;
  721.     }
  722.     if (`checkBoxGrp -exists poseOption`) {
  723.         optionVar -intValue poseOption
  724.             `checkBoxGrp -query -value1 poseOption`;
  725.     }
  726.     if (`checkBoxGrp -exists clipOption`) {
  727.         optionVar -intValue clipOption
  728.             `checkBoxGrp -query -value1 clipOption`;
  729.     }
  730.     if (`checkBoxGrp -exists expressionOption`) {
  731.         optionVar -intValue expressionOption
  732.             `checkBoxGrp -query -value1 expressionOption`;
  733.     }
  734.     if (`checkBoxGrp -exists groupIDnOption`) {
  735.         optionVar -intValue groupIDnOption
  736.             `checkBoxGrp -query -value1 groupIDnOption`;
  737.     }
  738.     if (`checkBoxGrp -exists animationCurveOption`) {
  739.         optionVar -intValue animationCurveOption
  740.             `checkBoxGrp -query -value1 animationCurveOption`;
  741.     }
  742.     if (`checkBoxGrp -exists shaderOption`) {
  743.         optionVar -intValue shaderOption
  744.             `checkBoxGrp -query -value1 shaderOption`;
  745.     }
  746.     if (`checkBoxGrp -exists cachedOption`) {
  747.         optionVar -intValue cachedOption
  748.             `checkBoxGrp -query -value1 cachedOption`;
  749.     }
  750.     if (`checkBoxGrp -exists transformOption`) {
  751.         optionVar -intValue transformOption
  752.             `checkBoxGrp -query -value1 transformOption`;
  753.     }
  754.     if (`checkBoxGrp -exists displayLayerOption`) {
  755.         optionVar -intValue displayLayerOption
  756.             `checkBoxGrp -query -value1 displayLayerOption`;
  757.     }
  758.     if (`checkBoxGrp -exists renderLayerOption`) {
  759.         optionVar -intValue renderLayerOption
  760.             `checkBoxGrp -query -value1 renderLayerOption`;
  761.     }
  762.     if (`checkBoxGrp -exists setsOption`) {
  763.         optionVar -intValue setsOption
  764.             `checkBoxGrp -query -value1 setsOption`;
  765.     }
  766.     if (`checkBoxGrp -exists partitionOption`) {
  767.         optionVar -intValue partitionOption
  768.             `checkBoxGrp -query -value1 partitionOption`;
  769.     }
  770.     if (`checkBoxGrp -exists locatorOption`) {
  771.         optionVar -intValue locatorOption
  772.             `checkBoxGrp -query -value1 locatorOption`;
  773.     }
  774.     if (`checkBoxGrp -exists ptConOption`) {
  775.         optionVar -intValue ptConOption
  776.             `checkBoxGrp -query -value1 ptConOption`;
  777.     }
  778.     if (`checkBoxGrp -exists pbOption`) {
  779.         optionVar -intValue pbOption
  780.             `checkBoxGrp -query -value1 pbOption`;
  781.     }
  782.     if (`checkBoxGrp -exists snapshotOption`) {
  783.         optionVar -intValue snapshotOption
  784.             `checkBoxGrp -query -value1 snapshotOption`;
  785.     }
  786.     if (`checkBoxGrp -exists unitConversionOption`) {
  787.         optionVar -intValue unitConversionOption
  788.             `checkBoxGrp -query -value1 unitConversionOption`;
  789.     }
  790.     if (`checkBoxGrp -exists referencedOption`) {
  791.         optionVar -intValue referencedOption
  792.             `checkBoxGrp -query -value1 referencedOption`;
  793.     }
  794.     if (`checkBoxGrp -exists brushOption`) {
  795.         optionVar -intValue brushOption
  796.             `checkBoxGrp -query -value1 brushOption`;
  797.     }
  798. }
  799.  
  800.  
  801. //
  802. //    reset the option values
  803. //
  804. global proc cleanUpSceneSetup(string $parent, int $forceFactorySettings)
  805. {
  806.     setOptionVars($forceFactorySettings);
  807.     
  808.     if (`checkBoxGrp -exists nurbsSrfOption`) {
  809.         checkBoxGrp -edit
  810.             -value1 `optionVar -query nurbsSrfOption`
  811.             nurbsSrfOption;
  812.     }
  813.     if (`checkBoxGrp -exists nurbsCrvOption`) {
  814.         checkBoxGrp -edit
  815.             -value1 `optionVar -query nurbsCrvOption`
  816.             nurbsCrvOption;
  817.     }
  818.     if (`checkBoxGrp -exists deformerOption`) {
  819.         checkBoxGrp -edit
  820.             -value1 `optionVar -query deformerOption`
  821.             deformerOption;
  822.     }
  823.     if (`checkBoxGrp -exists clipOption`) {
  824.         checkBoxGrp -edit
  825.             -value1 `optionVar -query clipOption`
  826.             clipOption;
  827.     }
  828.     if (`checkBoxGrp -exists poseOption`) {
  829.         checkBoxGrp -edit
  830.             -value1 `optionVar -query poseOption`
  831.             poseOption;
  832.     }
  833.     if (`checkBoxGrp -exists expressionOption`) {
  834.         checkBoxGrp -edit
  835.             -value1 `optionVar -query expressionOption`
  836.             expressionOption;
  837.     }
  838.     if (`checkBoxGrp -exists groupIDnOption`) {
  839.         checkBoxGrp -edit
  840.             -value1 `optionVar -query groupIDnOption`
  841.             groupIDnOption;
  842.     }
  843.     if (`checkBoxGrp -exists animationCurveOption`) {
  844.         checkBoxGrp -edit
  845.             -value1 `optionVar -query animationCurveOption`
  846.             animationCurveOption;
  847.     }
  848.     if (`checkBoxGrp -exists shaderOption`) {
  849.         checkBoxGrp -edit
  850.             -value1 `optionVar -query shaderOption`
  851.             shaderOption;
  852.     }
  853.     if (`checkBoxGrp -exists cachedOption`) {
  854.         checkBoxGrp -edit
  855.             -value1 `optionVar -query cachedOption`
  856.             cachedOption;
  857.     }
  858.     if (`checkBoxGrp -exists transformOption`) {
  859.         checkBoxGrp -edit
  860.             -value1 `optionVar -query transformOption`
  861.             transformOption;
  862.     }
  863.     if (`checkBoxGrp -exists displayLayerOption`) {
  864.         checkBoxGrp -edit
  865.             -value1 `optionVar -query displayLayerOption`
  866.             displayLayerOption;
  867.     }
  868.     if (`checkBoxGrp -exists renderLayerOption`) {
  869.         checkBoxGrp -edit
  870.             -value1 `optionVar -query renderLayerOption`
  871.             renderLayerOption;
  872.     }
  873.     if (`checkBoxGrp -exists setsOption`) {
  874.         checkBoxGrp -edit
  875.             -value1 `optionVar -query setsOption`
  876.             setsOption;
  877.     }
  878.     if (`checkBoxGrp -exists partitionOption`) {
  879.         checkBoxGrp -edit
  880.             -value1 `optionVar -query partitionOption`
  881.             partitionOption;
  882.     }
  883.     if (`checkBoxGrp -exists locatorOption`) {
  884.         checkBoxGrp -edit
  885.             -value1 `optionVar -query locatorOption`
  886.             locatorOption;
  887.     }
  888.     if (`checkBoxGrp -exists ptConOption`) {
  889.         checkBoxGrp -edit
  890.             -value1 `optionVar -query ptConOption`
  891.             ptConOption;
  892.     }
  893.     if (`checkBoxGrp -exists pbOption`) {
  894.         checkBoxGrp -edit
  895.             -value1 `optionVar -query pbOption`
  896.             pbOption;
  897.     }
  898.     if (`checkBoxGrp -exists snapshotOption`) {
  899.         checkBoxGrp -edit
  900.             -value1 `optionVar -query snapshotOption`
  901.             snapshotOption;
  902.     }
  903.     if (`checkBoxGrp -exists unitConversionOption`) {
  904.         checkBoxGrp -edit
  905.             -value1 `optionVar -query unitConversionOption`
  906.             unitConversionOption;
  907.     }
  908.     if (`checkBoxGrp -exists referencedOption`) {
  909.         checkBoxGrp -edit
  910.             -value1 `optionVar -query referencedOption`
  911.             referencedOption;
  912.     }
  913.     if (`checkBoxGrp -exists brushOption`) {
  914.         checkBoxGrp -edit
  915.             -value1 `optionVar -query brushOption`
  916.             brushOption;
  917.     }
  918. }
  919.  
  920.  
  921. //-------------------------------------------------
  922.  
  923. //
  924. // Some Short delete procs.
  925. //
  926.  
  927. proc int isNodeUsed(string $node, int $minVal)
  928. //
  929. // Description:
  930. //      Function to return whether a node is used in the scene.
  931. //
  932. // Arguments:
  933. //      node    Name of the node to test.
  934. //      minVal  Minimum number of connections the node must have to be
  935. //              considered used (ie. a node must have more than this
  936. //              number to be considered used.
  937. //
  938. // Returns:
  939. //      1   - the node is used by the scene
  940. //      0   - this node doesn't have enough connections, its unused.
  941. //
  942. // Author:
  943. //      cdt (March 2002)
  944. //
  945. {
  946.     int $isUsed = 1;
  947.  
  948.     if ($node != "characterPartition") {
  949.         // sometimes related nodes might delete others on the
  950.         // list, so need to check if the node still exists.
  951.         string $reallyExist[] = `ls $node`;
  952.         
  953.         if (size($reallyExist) != 0) {
  954.             string $connectionList[] = `listConnections $node`;
  955.  
  956.             if (size($connectionList) <= $minVal)
  957.             {
  958.                 $isUsed = 0;
  959.             }
  960.         }
  961.     }
  962.  
  963.     return $isUsed;
  964. }
  965.  
  966. global proc deleteUnusedCommon(string $typ, int $minVal)
  967. {
  968.     int $i;
  969.     string $nodeList[] = `ls -typ $typ`;
  970.  
  971.     for ($i = 0; $i < size($nodeList); $i++) {
  972.         if (!isNodeUsed($nodeList[$i], $minVal)) {
  973.             deleteIfNotReferenced $nodeList[$i];
  974.         }
  975.     }
  976. }
  977.  
  978.  
  979. //
  980. // Delete Unused Sets.
  981. //
  982.  
  983. global proc deleteUnusedSets()
  984. {
  985.     string $sets[] = `ls -sets`;
  986.  
  987.     for( $set in $sets ) {
  988.         if (`objExists $set`) {
  989.             string $elements[] = `sets -q $set`;
  990.             if( `size $elements` < 1 ) {
  991.                 if( $set != "defaultLightSet" && $set != "defaultObjectSet" &&
  992.                     $set != "initialParticleSE" && $set != "initialShadingGroup") {
  993.                     deleteIfNotReferenced( $set );
  994.                 }
  995.             }
  996.         }
  997.     }
  998. }
  999.  
  1000. //  ====================== deleteUnusedExpressions ======================
  1001. //
  1002. //  Author:         Jonathan Southard
  1003. //  Creation Date:  March, 1999
  1004. //
  1005. //  Description:
  1006. //    Deletes all expression nodes which have no direct connections 
  1007. //  to any of their output attributes.  A unit node with nothing on 
  1008. //  the other side is considered not to be a direct connection, i.e. it is
  1009. //  skipped over.  Note we say "direct" connections.  An expression might 
  1010. //  be part of a connected group of nodes which were cut off from the 
  1011. //  rest of the scene, hence "not used," but this routine
  1012. //  does not attempt to depth-search the network to detect such situations.
  1013. // 
  1014. //  This routine deletes only "expression" nodes, not dynExpressions.  
  1015. //  dynExpressions are built into the particle shapes.
  1016. //
  1017. //  CAUTION: If you have an expression that executes Mel commands but
  1018. //  has no output connections, this routine *will* delete it.  Use cautiously!
  1019. //
  1020. //  INPUT ARGUMENTS
  1021. //      None.
  1022. // 
  1023. //  Return Value: 
  1024. //      int $deleteCount = 
  1025. //           number of expression nodes deleted
  1026. //
  1027. global proc int deleteUnusedExpressions() {
  1028.  
  1029.     int $deletedCount = 0;
  1030.  
  1031.     //  Get a list of all expression nodes.
  1032.     //
  1033.     string $nodeList[];
  1034.     clear( $nodeList );
  1035.     $nodeList = `ls -type expression`;
  1036.  
  1037.     // Iterate through list of nodes
  1038.     //
  1039.     int $i;
  1040.     int $nodeCount = size( $nodeList );
  1041.     for ($i = 0; $i  < $nodeCount; $i++)
  1042.     {
  1043.         // See if this node's "output" attribute has any
  1044.         // outgoing connections.
  1045.         //
  1046.         string $outputs[];
  1047.         clear( $outputs );
  1048.         $outputs = `listConnections -source false -destination true -skipConversionNodes true ($nodeList[$i]+".output")`;
  1049.         if( size( $outputs ) == 0 )        
  1050.         {
  1051.             if( deleteIfNotReferenced( $nodeList[$i] ) ) {
  1052.                 $deletedCount++;
  1053.             }
  1054.         }
  1055.     }
  1056.     return $deletedCount;                        
  1057. }
  1058.  
  1059. global proc deleteUnusedInUnusedHierarchy(string $typ, int $minVal)
  1060. //
  1061. // Description:
  1062. //      For each node of the specified type, delete it if it's unused and
  1063. //      all it's parents are also unused. This will delete only those
  1064. //      nodes of the specified type and will not the unused nodes in
  1065. //      the hierarchy. For example, if all nodes in the hierarchy: "group1
  1066. //      | group2 | curveShape1" are unused and typ is "curveShape"; only
  1067. //      the "curveShape" node will be deleted.
  1068. //
  1069. // Notes:
  1070. //      This method may be desireable over using deleteUnusedCommon in
  1071. //      situations where shape nodes are being cleaned up. For example,
  1072. //      even though a curve shape is unused we should still keep it in
  1073. //      the scene because the user may be using it to assist in picking
  1074. //      the hierarchy (BUG 163067).
  1075. //
  1076. // Author:
  1077. //      cdt (March 2002)
  1078. //
  1079. {
  1080.     string $nodeList[] = `ls -typ $typ`;
  1081.  
  1082.     string $parents[];
  1083.  
  1084.     for ($node in $nodeList) {
  1085.         if (!isNodeUsed($node, $minVal)) {
  1086.             // The shape is unused, check whether its parents are also unused.
  1087.  
  1088.             int $isUsed = 0;
  1089.  
  1090.             clear($parents); // reset, allParents() will append to list.
  1091.             getAllParents($node, $parents);
  1092.  
  1093.             for ($parent in $parents) {
  1094.                 if (isNodeUsed($parent, $minVal)) {
  1095.                     // At least one of the parents is used, keep the shape.
  1096.                     $isUsed = 1;
  1097.                     break;
  1098.                 }
  1099.             }
  1100.  
  1101.             if (!$isUsed) {
  1102.                 deleteIfNotReferenced $node;
  1103.             }
  1104.         }
  1105.     }
  1106. }
  1107.